Thanks to Adam Crump, I finally got snippets working in CFEclipse. Turns out, it was something rather trivial, but I'll save that for another post. One of the things that's kept me from completely switching from HomeSite + to CFEclipse is snippets. I have hundreds of them, and the thought of living without them makes me cringe.

Once snippets were successfully working for me in CFEclipse, I decided I needed a tool to convert them from HomeSite + format to CFEclipse's XML format. HomeSite stores two files for each snippet you create. Each filename is the actual name of the snippet you see in Homesite. One file has a .hss extension, and contains the "start" text of the snippet. The other file gets a .hse extension, and contains the "end" text for the snippet. With this in mind, I outlined what I wanted my converter tool to do:

  1. Read snippets directory recursively
  2. Cead .hss and .hse files - these contain the snippet text
  3. Create folders in eclipse snippet directory
  4. Wrap the snippet text in xml (eclipse snippet format). Name of snippet is filename from homesite
  5. Write out xml files in eclipse snippets directory

Sounds pretty simple, right? ColdFusion MX 7 added a new recurse attribute to the cfdirectory tag which actually makes the whole process pretty simple. Here's the code I came up with. I have to admit, it's been a good while since I've written any code, so this took me a bit longer than I'd like to admit. I was able to use the code to convert and copy all of my snippets over, including all folders and subfolders, in just a few seconds. As always, YMMV:

view plain print about
1<!---
21. read snippets directory recursively
32. read .hss and .hse files - these contain the snippet text
43. create folders in eclipse snippet directory
54. wrap the snippet text in xml (eclipse snippet format). Name of snippet is filename from homesite
65. write out xml files in eclipse snippets directory
7--->
8<!--- set homesite and eclipse snippet base directories --->
9<cfset sourceDir = "C:\Program Files\Macromedia\HomeSite+\UserData\Snippets">
10<cfset targetDir = "C:\_source\snippets">
11
12<!--- read in the snippet files and directories from homesite recursively - need mx 7 --->
13<cfdirectory
14    action="LIST"
15    directory="#sourceDir#"
16    name="dirList"
17    recurse="Yes"
18    sort="directory">
19
20<!--- strip out .hse and other files so only .hss and directories are left --->
21<cfquery name="theData" dbtype="query">
22    SELECT *
23    FROM dirList
24    WHERE type = 'dir'
25        OR    name like '%.hss'
26</cfquery>    
27
28<!--- loop over each directory, creating the same thing on the eclipse side --->
29<cfoutput query="theData" group="directory" groupcasesensitive="yes">
30    <cfset myDir = replace(directory, sourceDir, "")>
31    <cfif directory is not sourceDir>
32        <cfdirectory action="CREATE" directory="#targetDir##myDir#">
33    </cfif>
34
35    <cfoutput>
36        <cfif listLast(name, ".") is "hss" and type is "file">
37            <!--- read in the .hss file (start of a snippet) --->
38            <cffile action="READ" file="#directory#\#name#" variable="snippetStart">
39            <!--- read in the .hse file (end of a snippet) --->
40            <cffile action="READ" file="#directory#\#ReplaceNoCase(name,".hss",".hse")#" variable="snippetEnd">
41            
42<!--- create the xml for each eclipse version of the snippet --->
43<cfsavecontent variable="targetSnippet"><?xml version="1.0" encoding="utf-8"?>
44<snippet filetemplate="false" extension="cfm">
45<name>#ReplaceNoCase(name,".hss","")#</name>
46<help>#ReplaceNoCase(name,".hss","")#</help>
47<starttext><![CDATA[#snippetStart#]]></starttext>
48<endtext><![CDATA[#snippetEnd#]]></endtext>
49</snippet></cfsavecontent>    
50
51            <!--- write out each file on the eclipse side --->
52            <cffile action="WRITE" file="#targetDir#\#myDir#\#ReplaceNoCase(name,".hss",".xml")#" output="#targetSnippet#">        
53        </cfif>
54    </cfoutput>
55</cfoutput>
56
57All Finished!